garden/terra.fnl

231 lines
9.4 KiB
Plaintext
Raw Normal View History

2023-12-01 01:10:16 +00:00
(local fennel (require :fennel))
(fn safesym [name]
(let [str (tostring (gensym name))]
(str:gsub "[^%w_]" #(string.format "_%02x" ($:byte)))))
(fn kv-table? [tbl] ; this should be exported to macros but is not ;_;
(and (table? tbl) (not (sequence? tbl))))
(fn commasep [list f ?sep]
(table.concat (icollect [_ v (ipairs list)] (f v)) (or ?sep ", ")))
(fn kvcommasep [tbl f ?sep]
(commasep (. (getmetatable tbl) :keys) #(f $1 (. tbl $1)) ?sep))
(fn indent [str scope]
(.. (string.rep " " scope.indent) str))
(fn block [pre stmts post scope f]
(set scope.indent (+ scope.indent 2))
(local block (commasep stmts #(indent (f $1) scope) "\n"))
(set scope.indent (- scope.indent 2))
(.. pre "\n" block "\n" (indent post scope)))
(local extract {})
(fn extract.quotes-in-table [into tbl inputs locals]
(collect [k v (pairs tbl) &into into] k (extract.quotes v inputs locals)))
(fn extract.ensure-input [input inputs]
(var found false)
(each [_ sym (ipairs inputs)]
(when (= sym input) (set found true)))
(when (not found) (table.insert inputs input))
input)
(fn extract.quotes [form inputs locals]
(case form
(where [q ref] (list? form) (sym? q) (sym? ref) (= (tostring q) :quote))
(let [localref (. locals (tostring ref))]
(if localref (extract.ensure-input (sym localref) inputs)
(error (.. "Unknown local: " (tostring ref)))))
(where l (list? l)) (extract.quotes-in-table (list) l inputs locals)
(where s (sequence? s)) (extract.quotes-in-table (sequence) s inputs locals)
(where t (kv-table? t)) (extract.quotes-in-table {} t inputs locals)
_ form))
2023-12-01 01:10:16 +00:00
(fn new-scope []
{:locals {}
:env {}
:input []
:indent 0
2023-12-01 01:10:16 +00:00
:push (fn [self] (set self.locals (setmetatable {} {:__index self.locals})))
:pop (fn [self] (set self.locals (. (getmetatable self.locals) :__index)))
:with (fn [self f]
(self:push)
(local result (f))
(self:pop)
result)
2023-12-01 01:10:16 +00:00
:expr (fn [self expr]
(if (and (sym? expr) (not (multi-sym? expr))) (self:env-ref expr)
(= (type expr) :number) (tostring expr)
(= expr nil) :nil
(let [name (safesym :inline-expr)
arglist (sequence)
expr (extract.quotes expr arglist self.locals)
bare-ref? (= (length arglist) 0)
expr (if bare-ref? expr `(fn ,arglist ,expr))
ref (if bare-ref? name (.. name "(" (commasep arglist #(tostring $1)) ")"))]
(table.insert self.input {: name : expr})
ref)))
2023-12-01 01:10:16 +00:00
:env-ref (fn [self symbol]
(let [name (tostring symbol)
loc (. self.env name)]
(if loc loc
(let [envloc (safesym name)]
(tset self.env name envloc)
(table.insert self.input {:name envloc :expr (sym name)})
envloc))))
2023-12-01 01:10:16 +00:00
:reference (fn [self symbol]
(let [name (tostring symbol)
loc (. self.locals name)]
(if loc loc (self:env-ref symbol))))
2023-12-01 01:10:16 +00:00
:addlocal (fn [self symbol]
(let [name (tostring symbol)
loc (safesym name)]
(tset self.locals name loc)
loc))})
2023-12-01 01:10:16 +00:00
(local comp {})
2023-12-01 01:10:16 +00:00
(local forms {})
(fn comp.expr [form scope]
2023-12-01 01:10:16 +00:00
(case form
(where [head & rest] (sym? head) (list? form) (. forms (tostring head)))
2023-12-01 01:10:16 +00:00
((. forms (tostring head)) rest scope)
(where [head & rest] (list? form))
(.. (comp.expr head scope) "(" (commasep rest #(comp.expr $1 scope)) ")")
2023-12-01 01:10:16 +00:00
(where [array] (sequence? form) (= (length form) 1))
(.. "@" (comp.expr array scope))
2023-12-01 01:10:16 +00:00
(where [array & indexes] (sequence? form))
(.. "(" (comp.expr array scope) ")" (table.concat (icollect [_ i (ipairs indexes)] (.. "[" (comp.expr i scope) "]"))))
2023-12-01 01:10:16 +00:00
(where struct (kv-table? struct))
(.. "{ " (kvcommasep struct #(.. (tostring $1) " = " (comp.expr $2 scope))) " }")
2023-12-01 01:10:16 +00:00
(where multisym (multi-sym? multisym))
(string.gsub (tostring multisym) "[^.:]+" #(scope:reference $1) 1)
(where symbol (sym? symbol))
(scope:reference symbol)
(where lit (or (= (type lit) :string) (= (type lit) :number) (= (type lit) :nil)))
(scope:expr lit)
2023-12-01 01:10:16 +00:00
_ (error (.. "Failed to parse expression: " (view form)))))
(local type-constructors {})
(fn comp.type [typ scope]
2023-12-01 01:10:16 +00:00
(case typ
(where [innertyp index] (sequence? typ))
(.. "(" (comp.type innertyp scope) ")[" (comp.type index scope) "]")
2023-12-01 01:10:16 +00:00
(where [innertyp] (sequence? typ) (= (length typ) 1))
(.. "&" (comp.type innertyp scope))
2023-12-01 01:10:16 +00:00
(where struct (kv-table? struct))
(.. "struct { " (kvcommasep struct #(comp.type-field $1 $2 scope)) " }")
2023-12-01 01:10:16 +00:00
(where [head & args] (list? typ) (sym? head) (. type-constructors (tostring head)))
((. type-constructors (tostring head)) args scope)
2023-12-01 01:10:16 +00:00
(where [head & args] (list? typ))
(.. (comp.type head scope) "(" (commasep args #(comp.type $1 scope)) ")")
(where multisym (multi-sym? multisym))
(string.gsub (tostring multisym) "[^.:]+" #(scope:reference $1) 1)
_ (scope:expr typ)))
2023-12-01 01:10:16 +00:00
(fn comp.type-field [name typ scope]
(case name
(where name (sym? name) (not (multi-sym? name)))
(.. (tostring name) " : " (comp.type typ scope))
2023-12-01 01:10:16 +00:00
:union
(.. "union { " (kvcommasep typ #(comp.type-field $1 $2 scope)) " }") ; unions shouldn't nest :/
_ (error (.. "Invalid field name: " (view name)))))
(fn arglist-type [arglist scope] (.. "{ " (commasep (or arglist []) #(comp.type $1 scope)) " }"))
(tset type-constructors :-> (fn [[in out] scope] (.. (arglist-type in scope) " -> " (arglist-type out scope))))
(tset type-constructors :& (fn [[typ] scope] (.. :& (comp.type typ scope))))
(tset type-constructors :$ (fn [typs scope] (.. "tuple(" (commasep typs #(comp.type $1 scope)) ")")))
(fn type-constructors.unquote [[expr] scope] (scope:expr expr))
2023-12-01 01:10:16 +00:00
(fn forms.rawterra [[text] scope] text)
(fn forms.var [defn scope]
(case defn
[name typ initval] (.. "var " (scope:addlocal name) " : " (comp.type typ scope) " = " (comp.expr initval scope))
[name initval] (.. "var " (scope:addlocal name) " = " (comp.expr initval scope))))
2023-12-01 01:10:16 +00:00
(fn forms.do [stmts scope]
(scope:with #(block :do stmts :end scope #(comp.expr $1 scope))))
2023-12-01 01:10:16 +00:00
(fn find-ival [tbl pred]
(var ival nil)
(each [i val (ipairs tbl)]
(when (pred val) (set ival i)))
ival)
2023-12-01 01:10:16 +00:00
(fn forms.def [[arglist & stmts] scope]
(scope:with #(let [iarg-return-sep (find-ival arglist #(and (sym? $1) (= (tostring $1) ":")))
argpairs (fcollect [i 1 (length arglist) 2 &until (= i iarg-return-sep)]
{:name (. arglist i) :type (. arglist (+ i 1))})
rettyps (when iarg-return-sep (icollect [i typ (ipairs arglist)] (when (> i iarg-return-sep) typ)))
rettyp (if rettyps (.. ": { " (commasep rettyps #(comp.type $1 scope)) " }") "")
argdefs (commasep argpairs #(.. (scope:addlocal $1.name) " : " (comp.type $1.type scope)))]
(block (.. "terra (" argdefs ")" rettyp) stmts :end scope #(comp.expr $1 scope)))))
(fn forms.return [[expr] scope] (.. "return " (comp.expr expr scope)))
(fn forms.cast [[typ expr] scope]
(.. "([" (comp.type typ scope)"](" (comp.expr expr scope) "))"))
(fn forms.unquote [[expr] scope] (.. "([" (scope:expr expr) "])"))
(tset forms :& (fn [[expr] scope] (.. :& (comp.expr expr scope))))
(tset forms :$ (fn [items scope] (.. "{ " (commasep items #(comp.expr $1 scope)) " }")))
2023-12-01 01:10:16 +00:00
(fn def-infix [fnlop luaop]
(tset forms fnlop (fn [[left right] scope]
(.. "(" (comp.expr left scope) " " luaop " " (comp.expr right scope) ")"))))
2023-12-01 01:10:16 +00:00
(each [_ op (ipairs [:+ :- :* :/ :% :< :<= :> :>= :and :or :not :^ :<< :>>])]
(def-infix op op))
(def-infix := :==)
(def-infix :not= "~=")
(fn forms.set [[left right] scope]
(.. (comp.expr left scope) " = (" (comp.expr right scope) ")"))
2023-12-01 01:10:16 +00:00
(fn comp.quote [stmts scope]
(if (= (length stmts) 1) (.. "`(" (comp.expr (. stmts 1) scope) ")")
(.. "quote\n" (commasep stmts #(comp.expr $1 scope)) "\nend")))
(fn comp.global [[typ initial-val] scope]
(.. "global(" (comp.type typ scope) "," (comp.expr initial-val scope) ")"))
2023-12-01 01:10:16 +00:00
(fn build [expr compiler]
(let [scope (new-scope)
terra-expr (compiler expr scope)
env-setup (if (= (length scope.input) 0) ""
(.. "local " (commasep scope.input #$1.name) " = ...\n"))
compiled (.. env-setup "return " terra-expr)
call `((terralib.loadstring ,compiled))]
(icollect [_ {: expr} (ipairs scope.input) &into call] expr)
call))
(fn terra [expr] (build expr comp.expr))
(fn ttype [expr] (build expr comp.type))
2023-12-01 01:10:16 +00:00
(fn def [...] (terra `(,(sym :def) ,...)))
(fn q [...] (build [...] comp.quote))
(fn static [typ initial-value] (build [typ initial-value] comp.global))
2023-12-01 01:10:16 +00:00
(fn unterra [...] (view (macroexpand (terra ...))))
(fn untype [...] (view (macroexpand (ttype ...))))
2023-12-01 01:10:16 +00:00
{: terra : ttype : def : q : static : unterra : untype}