: titlec ( c -- )
  textx @ texty @ 40 * + swap text-color @ rawtextc
  1 textx +! ;
: textline ( w r m l )
  textleft @ textx !
  titlec <rot 1 for dup titlec next drop titlec
  8 texty +! ;
: boxtop ( w -- ) 184 205 213 textline ;
: boxmid ( w -- ) 179 32 179 textline ;
: boxbot ( w -- ) 190 205 212 textline ;
: box ( w h x y -- )
  texty ! textleft !
  over boxtop
  1 for dup boxmid next
  boxbot ;

: strlen ( s -- n ) 0 swap begin dup b@ while 1 + swap 1 + swap repeat drop ;
: titles ( s -- ) begin dup b@ dup while titlec 1 + repeat drop drop ;
: optionbg ( y -- ) texty ! 20 boxmid -8 texty +! ;
: option ( s -- ) dup strlen 1 >> 19 swap - textx ! titles ;

: startgame ( n -- ) s" title" loadscr s" start.jor" loadjor ;
: menu-opts
  s" New Game" :| 1 startgame |; yield
  s" Continue" ' noop yield
  s" Register Today!" ' noop yield
  s" Quit" ' quit yield
  done ;
var menu-selected
: menu-y ( i -- y ) 10 * 90 + ;
: draw-menu
  0 menu-opts each drop
    over menu-y optionbg
    over menu-selected @ = if LCYAN else WHITE then text-color !
    option
    1 +
  more drop ;

: exec-selected 0 menu-opts each swap drop
    over menu-selected @ = if execute break else drop then
    1 +
  more drop ;

: menu-count 0 menu-opts each drop drop 1 + more ;
: menu-select ( di -- ) menu-selected menu-count +!cycle draw-menu ;

:noname
  fuck s" title" loadscr
  20 9 9 72 box
  draw-menu
  :| ^ENTER key-pressed if exec-selected then
     ^UP    key-pressed if -1 menu-select then
     ^DOWN  key-pressed if  1 menu-select then
     ^ESC   key-pressed if quit then
  |; ' tick redefine ; checkpoint title