( L E V E L 0 0 0 0 1 )

: intro
  30 sleep
  1 quaking !
  30 sleep
  jaye say" Woah!!..."
  hide-footer
  10 sleep
  0 quaking !
  jaye say" That was an earthquake!"
;

objects: O

defer last-term

12 9 door d1
' d1 12 8 switch s1
' last-term 15 8 computer c1

7 6 door d2
' d2 6 6 switch s2
' c1 1 4 computer c2
' c2 ' last-term redefine

lev00002.jor 10 0 exitdoor dexit
' dexit 9 0 scanner sexit

d1 :noname
  dup EVTOUCH = isjaye? and d1 DOOR-CLOSED entity>tile? and if
    jaye say" It won't open!"
  then chain-listener ;

c1 :noname
  dup EVTOUCH = isjaye? and if
    player.state HASNEUT f@ not if
      jaye say" Maybe Neut can help."
      neut say" NEUT v0.71.4rc12\ONLINE"
      neut say" PRESS SPACE TO TAKE CONTROL"
      c1 entity>pos pneut entity.pos!
      1 player.state HASNEUT f!
    else
      jaye say" Neut is running now.\I can hit the space bar\to control them."
    then
  then chain-listener ;
c2 :noname
  dup EVTOUCH = isjaye? and if
    c2 COMP-OFF entity>tile? if
      jaye say" Looks like there's still\power to this terminal."
    then
    jaye say" If I turn a terminal on,\Neut can use it to\travel through the network."
  then chain-listener ;

sexit :noname
  dup EVTOUCH = isjaye? and if
    jaye say" It's a card scanner.\It should open this door."
    jaye say" It's not reading my card\for some reason.\Quake must've damaged it."
    jaye say" Neut might be able to\hack it..."
  then chain-listener ;

:noname
  reset-level O

  s" lev00001.map" load-map
  0 player.state HASNEUT f!
  14 9 tile>world pjaye entity.pos!
  c1 entity>pos pneut entity.pos!

  ' intro sched

; ' onload redefine